SUMMARY = "PJSIP is a free and open source multimedia communication library written in C language"
DESCRIPTION = "PJSIP is a free and open source multimedia communication library written in C language \
               implementing standard based protocols such as SIP, SDP, RTP, STUN, TURN, and ICE. \
               It combines signaling protocol (SIP) with rich multimedia framework and NAT traversal \
               functionality into high level API that is portable and suitable for almost any type \
               of systems ranging from desktops, embedded systems, to mobile handsets."

HOMEPAGE = "http://www.pjsip.org"
BUGTRACKER = "https://trac.pjsip.org/repos/report"

PRIORITY = "optional"

LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"

DEPENDS = "alsa-lib openssl util-linux"
PARALLEL_MAKE = ""

SRC_URI = "http://www.pjsip.org/release/${PV}/pjproject-${PV}.tar.bz2"
SRC_URI[md5sum] = "6487d54213f270d307eaa60efc9f56f3"
SRC_URI[sha256sum] = "503d0bd7f9f13dc1492ac9b71b761b1089851fbb608b9a13996edc3c42006f79"

#add patches to original pjproject here
SRC_URI += "file://0001_pjproject_add_config_site.patch"

inherit autotools-brokensep pkgconfig

EXTRA_OECONF += "--enable-epoll --disable-video --disable-libwebrtc"

do_configure_prepend() {
    export LD="${CC}"
    export CFLAGS="-DNDEBUG"
}

do_install_prepend() {
    install -d ${D}/usr/bin
    install -m 755 ${S}/pjsip-apps/bin/pj* ${D}/usr/bin
}

do_install_append() {
    # remove the absolute path to the host's include dir
    sed -i 's:\-I/usr/include::' ${D}/usr/lib/pkgconfig/libpjproject.pc
    # remove the fdebug-prefix-map options
    sed -i 's:\-fdebug-prefix-map[a-zA-Z0-9\._\/=\-]*::g' ${D}/usr/lib/pkgconfig/libpjproject.pc

    #change user to root to stop QA from complaining about host contamination
    chown -R root:root ${D}${libdir}
}